home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh5x
/
sh55a.d64
/
demo.show pic
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
2KB
|
76 lines
100 IF M=0 THEN M=1:LOAD "SHOW PIC.52480",8,1
110 REM ******************************
120 REM * *
130 REM * BASIC DEMO ZUR *
140 REM * "SHOW PIC.52480" - ROUTINE *
150 REM * *
160 REM ******************************
170 REM
180 REM NAMEN EINGEBEN
190 REM
200 PRINT:PRINT:PRINT "NAME DES BILDES"
210 PRINT "(ODER $ FUER DIRECTORY)"
220 A$="":INPUT A$:IF A$="$" THEN 450
230 REM
240 REM BILD LADEN & ZEIGEN
250 REM
260 SYS 52480,8,A$,1
270 REM
280 REM TASTENDRUCK ABWARTEN
290 REM
300 GET A$:IFA$="" THEN 300
310 REM
320 REM TEXTMODUS EINSCHALTEN
330 REM
340 SYS 52480,8,"",0
350 PRINT"WOLLEN SIE DAS BILD NOCH EINMAL SEHEN"
360 INPUT A$:IF LEFT$(A$,1)<>"J" THEN 200
370 REM
380 REM BILD NOCH EINMAL ZEIGEN
390 REM
400 SYS 52480,8,"",1
410 GOTO 300
420 REM
430 REM DIRECTORY ZEIGEN
440 REM
450 OPEN 1,8,0,"$":POKE781,1:SYS65478:GET A$,A$:Z$=CHR$(0)
460 GET A$,A$,L$,H$:IF ST THEN SYS 65484:CLOSE1:GOTO 200
465 PRINTASC(L$+Z$)+256*ASC(H$+Z$);
466 GET A$,B$,C$,D$,E$,F$,G$,H$,I$,J$,K$,L$,M$,N$,O$,P$,Q$,R$,S$,T$,U$,V$,W$,X$
467 PRINT A$B$C$D$E$F$G$H$I$J$K$L$M$N$O$P$Q$R$S$T$U$V$W$X$;
470 GET A$,B$:IF A$ THEN PRINT A$B$;:GOTO 470
480 PRINTA$:GOTO 460
490 CLOSE1:GOTO 200
500 REM
510 REM SYNTAX DES "SYS-BEFEHLS" :
520 REM
530 REM SYS 52480,GERAET,"NAME",MODUS
540 REM
550 REM GERAET : GERAETENUMMER
560 REM 1=DATAS. 8=FLOPPY ...
570 REM
580 REM "NAME" : PROGRAMMNAME
590 REM Z.B. "[B]TEST"
600 REM WIRD ALS NAME NUR ""
610 REM (LEERSTRING) ANGEGEBEN
620 REM WIRD KEIN NEUES BILD
630 REM GELADEN (UM NUR IN DEN
640 REM TEXT-/GRAFIKMODUS UM-
650 REM ZUSCHALTEN
660 REM
670 REM MODUS : ZAHL VON 0 BIS 2
680 REM 0=TEXTMOD. EINSCHALTEN
690 REM 1=GRAFIK ZEIGEN
700 REM 2=ALTEN MODUS BEIBE-
710 REM HALTEN (NUR SINNVOLL
720 REM WENN AUCH EIN BILD
730 REM GELADEN WIRD,DA
740 REM SONST GAR NICHTS
750 REM PASSIERT)
760 REM
770 REM ES IST DARAUF ZU ACHTEN, DASS
780 REM DAS BILD AUCH WIRKLICH MIT
790 REM "AMICA PAINT" GESPEICHERT
800 REM WURDE, SONST IST EIN ABSTURZ
810 REM DES RECHNERS MOEGLICH